การใช้งาน ZX-PSX ร่วมกับ POP-BOT32i Rover Kit Plus

#include "POP32.h"
#include "PsxLib.h"
Psx Psx;
// Assign names to the pin connections used to connect to the joystick receiver.
#define dataPin PA0
#define commandPin PA1
#define selectPin PA2
#define clockPin PA3
// Assign a name to the servo angle.
#define sv1_up 10
#define sv1_down 90
#define sv2_release 50
#define sv2_hold 105
int speed = 50; // Set the starting speed to 50%.
unsigned int data = 0; // Define a variable to store the button press status.
void setup() {
  Psx.setupPins(dataPin, commandPin, selectPin, clockPin, 10);
  oled.textSize(5);
  oled.text(0, 0, " %d  ", speed);
  oled.show();
  Psx.read();
}
void loop() {
  data = Psx.read();
  // Speed ​​adjustment system (L1/L2)
  if(data & 1024){ // L1 button 
    speed = constrain(speed + 10, 10, 100); // Increase speed by 10
    oled.text(0, 0, " %d  ", speed); oled.show();
    delay(200);
    Psx.read();
  }
  if(data & 256){ // L2 button 
    speed = constrain(speed - 10, 10, 100); // Reduce speed to 10.
    oled.text(0, 0, " %d  ", speed); oled.show();
    delay(200);
    Psx.read();
  }
  // Left analog joystick
  int ly = Psx.AnLy; // Retrieve the Y-axis position value.
  int lx = Psx.AnLx; // Retrieve the X-axis position value.
  int moveY = 0;
  int moveX = 0;
  // Y-axis (forward, backward)
  if (ly < 117) { // Check, push up.
    moveY = map(ly, 117, 0, 0, 100); // Convert to forward speed.
  }else if(ly > 137){ // Check, push down.
    moveY = map(ly, 137, 255, 0, -100); // Convert to backward speed.
  }
  // X-axis (left-right)
  if (lx < 118) { // Check, Push left.
    moveX = map(lx, 118, 0, 0, -100); // Convert to left speed.
  }else if(lx > 138){ // Check, Push right.
    moveX = map(lx, 138, 255, 0, 100);  // Convert to right speed.
  }
  // Combining values ​​to drive the motor.
  float ratio = speed / 100.0;
  int L_raw = moveY + moveX; // Calculate the left wheel speed.
  int R_raw = moveY - moveX; // Calculate the right wheel speed.
  // Prevent values ​​from exceeding 100 and prevent abnormal reverse rotation.
  L_raw = constrain(L_raw, -100, 100);
  R_raw = constrain(R_raw, -100, 100);
  int L_final = L_raw * ratio;
  int R_final = R_raw * ratio;
  if (moveY != 0 || moveX != 0) { // Check the movement of the joystick.
    fd2(L_final, R_final); // Motor is operating as calculated.
  }
  // Motor Control
  else if(data & 16)  {fd(speed); } // UP Button to forward
  else if(data & 64)  {bk(speed); } // Down Button to Backward
  else if(data & 32)  {sr(speed); } // Right Button to SpinRight
  else if(data & 128) {sl(speed); } // Left Button to SpinLeft
  else { 
    AO();
  }
  // Servo Control
  if (data & 4096)  servo(2, sv2_hold);    // Triangle button to servo hold
  if (data & 16384) servo(2, sv2_release); // Cross button to servo release
  if (data & 2048)  servo(1, sv1_up);      // L1 button to servo up
  if (data & 512)   servo(1, sv1_down);    // L2 button to servo down
  delay(20);
}